@echo off
setlocal
cd /d "%~dp0"

echo ==== 1. worker and NX processes ====
tasklist /FI "IMAGENAME eq run_journal.exe" | find /I "run_journal" >nul
if %errorlevel%==0 (echo worker RUNNING) else (echo worker NOT running)
tasklist /FI "IMAGENAME eq ugraf.exe" | find /I "ugraf.exe" >nul
if %errorlevel%==0 (echo NX ugraf RUNNING) else (echo NX ugraf not running)

echo ==== 2. job state files newest first ====
dir /b /o-d "jobs" 2>nul

echo ==== 3. output dir generated models ====
dir /b /s "output" 2>nul

echo ==== 4. latest done file content ====
set "doned="
for /f "delims=" %%f in ('dir /b /o-d "jobs\job_*.done" 2^>nul') do if not defined doned set "doned=%%f"
if defined doned (
  echo --- %doned% ---
  type "jobs\%doned%"
) else (
  echo no .done file yet
)

endlocal
